What percentage of our outgoing email goes to corporate providers?

[Jamie McClelland]

The concentration of ownership of email providers is having a disasterous effect on the ability of our movement to communicate.

In the name of stopping spam, corporate providers are blocking or moving into junk folders many of the messages are movement depends on to communicate with our bases.

This ticket is here to publicly track how many of May First Movement Technology's outgoing email messages are being delivered to the top three corporate email providers.

The numbers are generated using the awk program. To run yourself, first create a file called count-corporate-relays with the following contents:

# Set initial variables to zero.
BEGIN {         
  total=0
  google=0
  yahoo=0
  microsoft=0
}
        
{       
  # Only search for successfully sent messages to avoid counting emails twice
  # if they are deferred. Also, convert to lower case because MX records
  # come in all shapes and sizes.
  if (tolower($0) ~ /relay=[a-z0-9.-]+\.google\.com/ && /status=sent/) { 
    google++
    total++
  }
  else if (tolower($0) ~ /relay=[a-z0-9.-]+\.yahoodns\.net/ && /status=sent/) { 
    yahoo++ 
    total++
  }
  else if (tolower($0) ~ /relay=[a-z0-9.-]+\.protection\.outlook\.com/ && /status=sent/) { 
    microsoft++ 
    total++
  }
  # Keep a total count of sent messages not sent to these providers. Be sure to
  # exclude 127.0.0.1 to avoid counting email sent to internal spam/antivirus
  # software twice.
  else if (/status=sent/ && /relay=[^(127\.0\.0\.1)]/) { 
    total++ 
  }
}
  
END {         
  printf "Total: %d\n", total
  printf "Google: %d (%.2f)\n", google, google/total
  printf "Yahoo: %d (%.2f)\n", yahoo, yahoo/total
  printf "Microsoft: %d (%.2f)\n", microsoft, microsoft/total
}

Then, run with journalctl -u 'postfix*' | awk -f count-corporate-relays

[Jamie McClelland]

May First uses separate relays for bulk mail vs regular mail. Here's the output for one of our bulk mail relays:

Total: 109095
Google: 39803 (0.36)
Yahoo: 20874 (0.19)
Microsoft: 13169 (0.12)

And here are the stats for an individual mail relay:

Google: 4678 (0.27)
Yahoo: 504 (0.03)
Microsoft: 1265 (0.07)

It's interesting to note a much lower dependence on corporate email for individual email messages compared with bulk messages.